uuid() sometimes yields same result over different query solutions

[fkleedorfer]

(not sure where else to post this.. the workbench seems to be the next best thing)

To reproduce: create a new repository and insert this ttl into the default graph:

@prefix ex:<http://example.com/ns/>
@prefix :<http://example.com/model/>
:one a ex:Number .
:two a ex:Number .
:three a ex:Number .
:me a ex:Person  .

Then, the query

PREFIX ex: <http://example.com/ns/>
select ?s (uuid() as ?u) where {
    ?s a ex:Number .
}

yields

?s	?u
<http://example.com/model/one>	<urn:uuid:a4a657c3-2edd-47d9-aa1c-096d4372cbd3>
<http://example.com/model/two>	<urn:uuid:a4a657c3-2edd-47d9-aa1c-096d4372cbd3>
<http://example.com/model/three>	<urn:uuid:a4a657c3-2edd-47d9-aa1c-096d4372cbd3>

i.e., the same uuid is generated for each solution
However, if we add an unbound variable to the projection, the uuid is different for each solution:

PREFIX ex: <http://example.com/ns/>
select ?s ?p (uuid() as ?u) where {
    ?s a ex:Number .
}

yields

?s	?p	?u
<http://example.com/model/one>		<urn:uuid:7d6d407f-8315-4236-bf9b-c2f4dd282a96>
<http://example.com/model/two>		<urn:uuid:5a271486-d65b-4dd3-bb71-ff4630a6b7a8>
<http://example.com/model/three>		<urn:uuid:c9f127d0-4cab-473e-a003-a3aeeb484086>

If I am not mistaken, the result should be consistently different for each query solution.

This problem concerns my GraphDB Free installation:

GraphDB 9.3.3
RDF4J 3.2.0
Connectors 12.1.1
OS Windows 10 10.0
Java AdoptOpenJDK 11.0.7

[VladimirAlexiev]

• it's a valid bug: https://www.w3.org/TR/sparql11-query/#func-uuid "Return a fresh IRI from the UUID URN scheme. Each call of UUID() returns a different UUID"
• @jeenbroekstra this sounds like an rdf4j bug?
• https://github.com/eclipse/rdf4j/issues?q=uuid and https://github.com/eclipse/rdf4j/issues?q=struuid doesn't find anything relevant

[VladimirAlexiev]

This returns the same bindings for ?s but does not expose the bug. Strange.

PREFIX : <http://example.com/model/>
select ?s (uuid() as ?u) where {
  values ?s {:one :two :three}
}

[damyan-ognyanov]

The bug is in our optimiser - it pushes the Extension (which binds ?u) on top of the plan and thus it is evaluated only once. Need to find a way to do not handle it in our query model so it is reevaluated for each of the solutions ...
Adding a fictive var in the projection avoids hitting the bug since we have a handling for Extension with more than one element and in such case we push its evaluation to RDF4J ...

[VladimirAlexiev]

tracked as https://ontotext.atlassian.net/browse/GDB-5053

[VladimirAlexiev]

Fixed, will be released in graphdb 9.5

[VladimirAlexiev]

There is a regression in GDB 11.1.1 at https://cim.ontotext.com/graphdb/sparql :
for each Substation, I’m trying to generate a new Diagram object with a unique uuid(). But all results have the same UUID:

PREFIX afn: <http://jena.apache.org/ARQ/function#>
PREFIX cimr: <https://cim.ucaiug.io/rules#>
PREFIX nc: <https://cim4.eu/ns/nc#>
PREFIX cim: <https://cim.ucaiug.io/ns#>

select ?diag ?sub ?UNDEF
#construct {
#  ?diag a cimr:Diagram; cimr:Diagram.kind cimr:DiagramKind.PowSyBl-SingleLineDiagram;
#    cim:IdentifiedObject.name ?diagName; cim:IdentifiedObject.mRID ?diagMrid; cim:IdentifiedObject.description ?diagDescr;
#    cimr:Diagram.PowerSystemResource ?sub; cimr:Diagram.mRIDs ?subMrid; cimr:Diagram.link ?link
# } 
where {
  ?sub a cim:Substation; cim:IdentifiedObject.name ?subName; cim:IdentifiedObject.mRID ?subMrid
  bind(uuid() as ?diag)
  bind(afn:localname(?diag) as ?diagMrid)
  bind(replace(?subName," ","-") as ?subSlug)
  bind(concat("Diagram of substation ",?subName) as ?diagName)
  bind(concat("PowSyBl Single-Line-Diagram of substation ",?subName) as ?diagDescr)
  bind(concat("PowSyBl-SLD-substation-",?subSlug,".svg") as ?link)
}

(The query has ?UNDEF in the projection to try the workaround described above "Adding a fictive var in the projection avoids hitting the bug").
EXPLAIN PLAN shows that bind(uuid() as ?diag) is done first. So I guess it's used as a constant for every result row, not reinvoked per row.

I found another workaround that works: put the data selection in a subquery to force running it first:

PREFIX afn: <http://jena.apache.org/ARQ/function#>
PREFIX cimr: <https://cim.ucaiug.io/rules#>
PREFIX nc: <https://cim4.eu/ns/nc#>
PREFIX cim: <https://cim.ucaiug.io/ns#>

select ?diag ?sub 
#construct {
#  ?diag a cimr:Diagram; cimr:Diagram.kind cimr:DiagramKind.PowSyBl-SingleLineDiagram;
#    cim:IdentifiedObject.name ?diagName; cim:IdentifiedObject.mRID ?diagMrid; cim:IdentifiedObject.description ?diagDescr;
#    cimr:Diagram.PowerSystemResource ?sub; cimr:Diagram.mRIDs ?subMrid; cimr:Diagram.link ?link
# } 
where {
  {select * {?sub a cim:Substation; cim:IdentifiedObject.name ?subName; cim:IdentifiedObject.mRID ?subMrid}}
  bind(uuid() as ?diag)
  bind(afn:localname(?diag) as ?diagMrid)
  bind(replace(?subName," ","-") as ?subSlug)
  bind(concat("Diagram of substation ",?subName) as ?diagName)
  bind(concat("PowSyBl Single-Line-Diagram of substation ",?subName) as ?diagDescr)
  bind(concat("PowSyBl-SLD-substation-",?subSlug,".svg") as ?link)
}

[svilenvelikov]

@VladimirAlexiev Reported this to the team. I'll link the ticket later.

[VladimirAlexiev]

Thanks! I reassigned GDB-5053 to Vladi