-/flake.nix at master · tomberek/- · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
{
  description = "Chained packages";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

  outputs = { self, nixpkgs }:
    let
      # System types to support.
      supportedSystems = [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin" ];

      # Helper functions
      forAllSystems = f: nixpkgs.lib.genAttrs supportedSystems (system: f system);
      nixpkgsFor = forAllSystems (system: import nixpkgs { inherit system;
          overlays = [ self.overlay ]; });

      makeMerger = self: packageset: packagesetfunc:
          let
            gen = name: paths: self.buildEnv {
              inherit name;
              paths = [
                (packagesetfunc (ps: paths))
              ] ++ paths ;
              ignoreCollisions = true;
              meta.mainProgram = let
                last = self.lib.last paths; in last.meta.mainProgram
                or (builtins.parseDrvName last.name).name;

              # Use lists not attrsets because order matters
              passthru = with builtins; mapAttrs (n: v: gen
                  (if length paths > 5 then "merged-environment" else "${name}-${n}")
                  (paths ++ [ v ])
                ) (self // packageset);
            };
          in gen "merged" [ ];
    in {
      overlay = self: super: {
        "-" = self.pkgsMerge;
        "+" = self.pkgsMerge;
        pkgsMerge = makeMerger self super (paths: paths {});
        python2With = makeMerger self super.python2Packages super.python2.withPackages;
        python3With = makeMerger self super.python3Packages super.python3.withPackages;
        python39With = makeMerger self super.python39Packages super.python39.withPackages;
        python310With = makeMerger self super.python310Packages super.python310.withPackages;
        haskellWith = makeMerger self super.haskellPackages super.haskellPackages.ghcWithPackages;
        perlWith = makeMerger self super.perlPackages super.perl.withPackages;
      };

      legacyPackages = forAllSystems (system: nixpkgsFor.${system});
      packages = forAllSystems (system: { inherit (nixpkgsFor.${system})
        pkgsMerge "+" "-" python3With ;});

      defaultPackage = forAllSystems (system: self.packages."${system}".pkgsMerge);
    };
}