penny/flake.nix at main · frectonz/penny · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
      };
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      rust-overlay,
    }:
    let
      forAllSystems =
        fn:
        let
          systems = [
            "x86_64-linux"
            "aarch64-linux"
            "aarch64-darwin"
          ];
          overlays = [ (import rust-overlay) ];
        in
        nixpkgs.lib.genAttrs systems (
          system:
          fn (
            import nixpkgs {
              inherit system overlays;
            }
          )
        );
    in
    {
      devShells = forAllSystems (pkgs: {
        default = pkgs.mkShell {
          buildInputs = [
            pkgs.fzf
            pkgs.pnpm
            pkgs.just
            pkgs.cmake
            pkgs.bacon
            pkgs.nodejs
            pkgs.openssl
            pkgs.cargo-dist
            pkgs.pkg-config
            pkgs.rust-analyzer
            pkgs.rust-bin.stable.latest.default
          ];
        };
      });

      packages = forAllSystems (
        pkgs:
        let
          rustPlatform = pkgs.makeRustPlatform {
            cargo = pkgs.rust-bin.stable.latest.default;
            rustc = pkgs.rust-bin.stable.latest.default;
          };

          pname = "penny";
          version = "0.0.19";
        in
        rec {
          ui = pkgs.stdenvNoCC.mkDerivation {
            pname = "${pname}-ui";
            version = version;

            src = ./ui;

            nativeBuildInputs = [
              pkgs.nodejs
              pkgs.pnpmConfigHook
              pkgs.pnpm
            ];

            pnpmDeps = pkgs.fetchPnpmDeps {
              inherit pname version;
              src = ./ui;
              pnpm = pkgs.pnpm;
              fetcherVersion = 3;
              hash =
                if pkgs.stdenv.isLinux then
                  "sha256-iFhK9U811SA6l64Sb98h8Hq9stCw3picqvLwvrLx3Ks="
                else
                  "sha256-lE3HeKgyWUmD4IXtj4RxwjFfFv371bjl+0U2s/Zj3SE=";
            };

            buildPhase = ''
              runHook preBuild

              pnpm build

              runHook postBuild
            '';

            installPhase = ''
              runHook preInstall

              cp -r dist $out
              echo -n "v${version}" > $out/VERSION

              runHook postInstall
            '';
          };

          default = rustPlatform.buildRustPackage {
            inherit pname version;
            src = self;
            buildInputs = [ pkgs.openssl ];
            nativeBuildInputs = [
              pkgs.pkg-config
              pkgs.perl
              pkgs.cmake
            ];
            cargoLock.lockFile = ./Cargo.lock;
            meta.mainProgram = "penny";

            preBuild = ''
              cp -pr --reflink=auto -- ${ui} ui/dist
            '';
          };

          image = pkgs.dockerTools.buildLayeredImage {
            name = pname;
            tag = "latest";
            created = "now";
            contents = [ default ];
            config.ENTRYPOINT = [ "/bin/penny" ];
          };

          deploy = pkgs.writeShellScriptBin "deploy" ''
            ${pkgs.skopeo}/bin/skopeo --insecure-policy copy docker-archive:${image} docker://docker.io/frectonz/penny:${version} --dest-creds="frectonz:$ACCESS_TOKEN"
            ${pkgs.skopeo}/bin/skopeo --insecure-policy copy docker://docker.io/frectonz/penny:${version} docker://docker.io/frectonz/penny:latest --dest-creds="frectonz:$ACCESS_TOKEN"
          '';
        }
      );

      overlays.penny = _final: prev: {
        penny = self.packages.${prev.system}.default;
      };
      overlays.default = self.overlays.penny;

      nixosModules.penny = import ./module.nix;
      nixosModules.default = self.nixosModules.penny;

      formatter = forAllSystems (
        pkgs:
        pkgs.treefmt.withConfig {
          runtimeInputs = [ pkgs.nixfmt ];
          settings = {
            on-unmatched = "info";
            formatter.nixfmt = {
              command = "nixfmt";
              includes = [ "*.nix" ];
            };
          };
        }
      );
    };
}