iOS: Migrate PlatformViewsController to Objective-C (#56790)

This migrates PlatformViewController from C++ to Objective-C. Generally, we try to keep the embedder interfaces and components written in Objective-C except for the few places where C++ interfaces are requried to interface with engine APIs such as Shell and PlatformView (e.g. the PlatformViewIOS subclass). Now that the implementation is Objective-C, the class and file are renamed to match Objective-C naming conventions.

This allows us to take advantage of ARC and weak references, which eliminates the need for std::shared_ptr, fml::WeakPtr etc. Further, this eliminates some particularly unintuitive behaviour wherein this class was owned via a std::shared_ptr held by FlutterEngine, and injected into many other classes (e.g. AccessibilityBridge) via a std::shared_ptr& reference -- such that only one instance of the std::shared_ptr actually ever existed, presumably to avoid std::shared_ptr refcounting overhead. Given that this overhead was only incurred a single time at engine initialisation, this seems like overkill. One might ask why it wasn't therefore held in a `std::unique_ptr` and a `std::unique_ptr&` reference passed around. Likely, this was because we wanted to take a `fml::WeakPtr` reference on it.

Regardless, none of this is necessary any longer now that we can inject `__weak FlutterPlatformViewsController*` instances to classes that use it.

To be clear, this patch makes no attempt whatsoever to simplify or clean up the interface or implementation of this class. This class ties together far too many concepts and is injected into far too many places, and we should break it up and simplify it. However, the goal of this patch was simply to port to an Objective-C interface that plays nicely with the rest of the iOS embedder. This does include a couple minor cleanups in `#include`/`#import` order and usage to match our style guide.

[C++, Objective-C, Java style guides]: https://github.com/flutter/engine/blob/main/CONTRIBUTING.md#style

Author: cbracken

ci/licenses_golden/licenses_flutter

@@ -44563,6 +44563,8 @@ ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterOverl
 ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformPlugin.h + ../../../flutter/LICENSE
 ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformPlugin.mm + ../../../flutter/LICENSE
 ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformPluginTest.mm + ../../../flutter/LICENSE
+ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformViewsController.h + ../../../flutter/LICENSE
+ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformViewsController.mm + ../../../flutter/LICENSE
 ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformViewsTest.mm + ../../../flutter/LICENSE
 ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformViews_Internal.h + ../../../flutter/LICENSE
 ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformViews_Internal.mm + ../../../flutter/LICENSE
@@ -44625,8 +44627,6 @@ ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/overlay_laye
 ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/overlay_layer_pool.mm + ../../../flutter/LICENSE
 ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/platform_message_response_darwin.h + ../../../flutter/LICENSE
 ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/platform_message_response_darwin.mm + ../../../flutter/LICENSE
-ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/platform_views_controller.h + ../../../flutter/LICENSE
-ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/platform_views_controller.mm + ../../../flutter/LICENSE
 ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/profiler_metrics_ios.h + ../../../flutter/LICENSE
 ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/profiler_metrics_ios.mm + ../../../flutter/LICENSE
 ORIGIN: ../../../flutter/shell/platform/darwin/ios/framework/Source/vsync_waiter_ios.h + ../../../flutter/LICENSE
@@ -47499,6 +47499,8 @@ FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterOverlay
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformPlugin.h
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformPlugin.mm
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformPluginTest.mm
+FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformViewsController.h
+FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformViewsController.mm
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformViewsTest.mm
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformViews_Internal.h
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/FlutterPlatformViews_Internal.mm
@@ -47561,8 +47563,6 @@ FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/overlay_layer_
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/overlay_layer_pool.mm
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/platform_message_response_darwin.h
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/platform_message_response_darwin.mm
-FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/platform_views_controller.h
-FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/platform_views_controller.mm
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/profiler_metrics_ios.h
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/profiler_metrics_ios.mm
 FILE: ../../../flutter/shell/platform/darwin/ios/framework/Source/vsync_waiter_ios.h

shell/platform/darwin/ios/BUILD.gn

@@ -79,6 +79,8 @@ source_set("flutter_framework_source") {
     "framework/Source/FlutterOverlayView.mm",
     "framework/Source/FlutterPlatformPlugin.h",
     "framework/Source/FlutterPlatformPlugin.mm",
+    "framework/Source/FlutterPlatformViewsController.h",
+    "framework/Source/FlutterPlatformViewsController.mm",
     "framework/Source/FlutterPlatformViews_Internal.h",
     "framework/Source/FlutterPlatformViews_Internal.mm",
     "framework/Source/FlutterPluginAppLifeCycleDelegate.mm",
@@ -120,8 +122,6 @@ source_set("flutter_framework_source") {
     "framework/Source/overlay_layer_pool.mm",
     "framework/Source/platform_message_response_darwin.h",
     "framework/Source/platform_message_response_darwin.mm",
-    "framework/Source/platform_views_controller.h",
-    "framework/Source/platform_views_controller.mm",
     "framework/Source/profiler_metrics_ios.h",
     "framework/Source/profiler_metrics_ios.mm",
     "framework/Source/vsync_waiter_ios.h",

shell/platform/darwin/ios/framework/Source/FlutterEngine.mm

@@ -105,6 +105,8 @@ @interface FlutterEngine () <FlutterIndirectScribbleDelegate,
 @property(nonatomic, readonly, assign) BOOL allowHeadlessExecution;
 @property(nonatomic, readonly, assign) BOOL restorationEnabled;
 
+@property(nonatomic, strong) FlutterPlatformViewsController* platformViewsController;
+
 // Maintains a dictionary of plugin names that have registered with the engine.  Used by
 // FlutterEngineRegistrar to implement a FlutterPluginRegistrar.
 @property(nonatomic, readonly) NSMutableDictionary* pluginPublications;
@@ -150,7 +152,6 @@ @implementation FlutterEngine {
   std::shared_ptr<flutter::ThreadHost> _threadHost;
   std::unique_ptr<flutter::Shell> _shell;
 
-  std::shared_ptr<flutter::PlatformViewsController> _platformViewsController;
   flutter::IOSRenderingAPI _renderingApi;
   std::shared_ptr<flutter::SamplingProfiler> _profiler;
 
@@ -211,7 +212,7 @@ - (instancetype)initWithName:(NSString*)labelPrefix
 
   _pluginPublications = [[NSMutableDictionary alloc] init];
   _registrars = [[NSMutableDictionary alloc] init];
-  [self recreatePlatformViewController];
+  [self recreatePlatformViewsController];
   _binaryMessenger = [[FlutterBinaryMessengerRelay alloc] initWithParent:self];
   _textureRegistry = [[FlutterTextureRegistryRelay alloc] initWithParent:self];
   _connections.reset(new flutter::ConnectionCollection());
@@ -262,9 +263,9 @@ - (void)setUpApplicationLifecycleNotifications:(NSNotificationCenter*)center {
                object:nil];
 }
 
-- (void)recreatePlatformViewController {
+- (void)recreatePlatformViewsController {
   _renderingApi = flutter::GetRenderingAPIForProcess(FlutterView.forceSoftwareRendering);
-  _platformViewsController.reset(new flutter::PlatformViewsController());
+  _platformViewsController = [[FlutterPlatformViewsController alloc] init];
 }
 
 - (flutter::IOSRenderingAPI)platformViewsRenderingAPI {
@@ -452,11 +453,7 @@ - (void)destroyContext {
   _shell.reset();
   _profiler.reset();
   _threadHost.reset();
-  _platformViewsController.reset();
-}
-
-- (std::shared_ptr<flutter::PlatformViewsController>&)platformViewsController {
-  return _platformViewsController;
+  _platformViewsController = nil;
 }
 
 - (NSURL*)observatoryUrl {
@@ -635,7 +632,7 @@ - (void)maybeSetupPlatformViewChannels {
     [self.platformViewsChannel
         setMethodCallHandler:^(FlutterMethodCall* call, FlutterResult result) {
           if (weakSelf) {
-            weakSelf.platformViewsController->OnMethodCall(call, result);
+            [weakSelf.platformViewsController onMethodCall:call result:result];
           }
         }];
 
@@ -777,11 +774,11 @@ - (BOOL)createShell:(NSString*)entrypoint
         if (!strongSelf) {
           return std::unique_ptr<flutter::PlatformViewIOS>();
         }
-        [strongSelf recreatePlatformViewController];
-        strongSelf->_platformViewsController->SetTaskRunner(
-            shell.GetTaskRunners().GetPlatformTaskRunner());
+        [strongSelf recreatePlatformViewsController];
+        strongSelf.platformViewsController.taskRunner =
+            shell.GetTaskRunners().GetPlatformTaskRunner();
         return std::make_unique<flutter::PlatformViewIOS>(
-            shell, strongSelf->_renderingApi, strongSelf->_platformViewsController,
+            shell, strongSelf->_renderingApi, strongSelf.platformViewsController,
             shell.GetTaskRunners(), shell.GetConcurrentWorkerTaskRunner(),
             shell.GetIsGpuDisabledSyncSwitch());
       };
@@ -1103,7 +1100,7 @@ - (void)flutterTextInputView:(FlutterTextInputView*)textInputView
   // Have to check in the next run loop, because iOS requests the previous first responder to
   // resign before requesting the next view to become first responder.
   dispatch_async(dispatch_get_main_queue(), ^(void) {
-    long platform_view_id = self.platformViewsController->FindFirstResponderPlatformViewId();
+    long platform_view_id = [self.platformViewsController firstResponderPlatformViewId];
     if (platform_view_id == -1) {
       return;
     }
@@ -1400,11 +1397,10 @@ - (FlutterEngine*)spawnWithEntrypoint:(/*nullable*/ NSString*)entrypoint
   // create call is synchronous.
   flutter::Shell::CreateCallback<flutter::PlatformView> on_create_platform_view =
       [result, context](flutter::Shell& shell) {
-        [result recreatePlatformViewController];
-        result->_platformViewsController->SetTaskRunner(
-            shell.GetTaskRunners().GetPlatformTaskRunner());
+        [result recreatePlatformViewsController];
+        result.platformViewsController.taskRunner = shell.GetTaskRunners().GetPlatformTaskRunner();
         return std::make_unique<flutter::PlatformViewIOS>(
-            shell, context, result->_platformViewsController, shell.GetTaskRunners());
+            shell, context, result.platformViewsController, shell.GetTaskRunners());
       };
 
   flutter::Shell::CreateCallback<flutter::Rasterizer> on_create_rasterizer =
@@ -1499,8 +1495,9 @@ - (void)registerViewFactory:(NSObject<FlutterPlatformViewFactory>*)factory
                               withId:(NSString*)factoryId
     gestureRecognizersBlockingPolicy:
         (FlutterPlatformViewGestureRecognizersBlockingPolicy)gestureRecognizersBlockingPolicy {
-  [_flutterEngine platformViewsController]->RegisterViewFactory(factory, factoryId,
-                                                                gestureRecognizersBlockingPolicy);
+  [_flutterEngine.platformViewsController registerViewFactory:factory
+                                                       withId:factoryId
+                             gestureRecognizersBlockingPolicy:gestureRecognizersBlockingPolicy];
 }
 
 @end

shell/platform/darwin/ios/framework/Source/FlutterEngine_Internal.h

@@ -46,7 +46,6 @@ NS_ASSUME_NONNULL_BEGIN
                                  base64Encode:(bool)base64Encode;
 
 - (FlutterPlatformPlugin*)platformPlugin;
-- (std::shared_ptr<flutter::PlatformViewsController>&)platformViewsController;
 - (FlutterTextInputPlugin*)textInputPlugin;
 - (FlutterRestorationPlugin*)restorationPlugin;
 - (void)launchEngine:(nullable NSString*)entrypoint
@@ -81,6 +80,7 @@ NS_ASSUME_NONNULL_BEGIN
             userData:(nullable void*)userData;
 
 @property(nonatomic, readonly) FlutterDartProject* project;
+
 @end
 
 NS_ASSUME_NONNULL_END

shell/platform/darwin/ios/framework/Source/FlutterPlatformViewsController.h

@@ -0,0 +1,152 @@
+// Copyright 2013 The Flutter Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef FLUTTER_SHELL_PLATFORM_DARWIN_IOS_FRAMEWORK_SOURCE_FLUTTERPLATFORMVIEWSCONTROLLER_H_
+#define FLUTTER_SHELL_PLATFORM_DARWIN_IOS_FRAMEWORK_SOURCE_FLUTTERPLATFORMVIEWSCONTROLLER_H_
+
+#include <Metal/Metal.h>
+#include <memory>
+#include <unordered_map>
+#include <unordered_set>
+
+#include "flutter/flow/surface.h"
+#include "flutter/fml/task_runner.h"
+#include "flutter/fml/trace_event.h"
+#include "impeller/base/thread_safety.h"
+#include "third_party/skia/include/core/SkRect.h"
+
+#import "flutter/shell/platform/darwin/common/framework/Headers/FlutterChannels.h"
+#import "flutter/shell/platform/darwin/ios/framework/Headers/FlutterPlatformViews.h"
+#import "flutter/shell/platform/darwin/ios/framework/Headers/FlutterPlugin.h"
+#import "flutter/shell/platform/darwin/ios/framework/Source/FlutterViewResponder.h"
+#import "flutter/shell/platform/darwin/ios/framework/Source/overlay_layer_pool.h"
+#import "flutter/shell/platform/darwin/ios/ios_context.h"
+
+@class FlutterTouchInterceptingView;
+@class FlutterClippingMaskViewPool;
+
+@interface FlutterPlatformViewsController : NSObject
+
+- (id)init NS_DESIGNATED_INITIALIZER;
+
+/// The task runner used to post rendering tasks to the platform thread.
+@property(nonatomic, assign) const fml::RefPtr<fml::TaskRunner>& taskRunner;
+
+/// The flutter view.
+@property(nonatomic, weak) UIView* flutterView;
+
+/// @brief The flutter view controller.
+@property(nonatomic, weak) UIViewController<FlutterViewResponder>* flutterViewController;
+
+/// @brief Retrieve the view controller.
+- (UIViewController<FlutterViewResponder>*)flutterViewController;
+
+/// @brief set the factory used to construct embedded UI Views.
+- (void)registerViewFactory:(NSObject<FlutterPlatformViewFactory>*)factory
+                              withId:(NSString*)factoryId
+    gestureRecognizersBlockingPolicy:
+        (FlutterPlatformViewGestureRecognizersBlockingPolicy)gestureRecognizerBlockingPolicy;
+
+/// @brief Mark the beginning of a frame and record the size of the onscreen.
+- (void)beginFrameWithSize:(SkISize)frameSize;
+
+/// @brief Cancel the current frame, indicating that no platform views are composited.
+///
+/// Additionally, reverts the composition order to its original state at the beginning of the
+/// frame.
+- (void)cancelFrame;
+
+/// @brief Record a platform view in the layer tree to be rendered, along with the positioning and
+///        mutator parameters.
+///
+/// Called from the raster thread.
+- (void)prerollCompositeEmbeddedView:(int64_t)viewId
+                          withParams:(std::unique_ptr<flutter::EmbeddedViewParams>)params;
+
+/// @brief Returns the`FlutterTouchInterceptingView` with the provided view_id.
+///
+/// Returns nil if there is no platform view with the provided id. Called
+/// from the platform thread.
+- (FlutterTouchInterceptingView*)flutterTouchInterceptingViewForId:(int64_t)viewId;
+
+/// @brief Determine if thread merging is required after prerolling platform views.
+///
+/// Called from the raster thread.
+- (flutter::PostPrerollResult)postPrerollActionWithThreadMerger:
+                                  (const fml::RefPtr<fml::RasterThreadMerger>&)rasterThreadMerger
+                                                impellerEnabled:(BOOL)impellerEnabled;
+
+/// @brief Mark the end of a compositor frame.
+///
+/// May determine changes are required to the thread merging state.
+/// Called from the raster thread.
+- (void)endFrameWithResubmit:(BOOL)shouldResubmitFrame
+                threadMerger:(const fml::RefPtr<fml::RasterThreadMerger>&)rasterThreadMerger
+             impellerEnabled:(BOOL)impellerEnabled;
+
+/// @brief Returns the Canvas for the overlay slice for the given platform view.
+///
+/// Called from the raster thread.
+- (flutter::DlCanvas*)compositeEmbeddedViewWithId:(int64_t)viewId;
+
+/// @brief Discards all platform views instances and auxiliary resources.
+///
+/// Called from the raster thread.
+- (void)reset;
+
+/// @brief Encode rendering for the Flutter overlay views and queue up perform platform view
+/// mutations.
+///
+/// Called from the raster thread.
+- (BOOL)submitFrame:(std::unique_ptr<flutter::SurfaceFrame>)frame
+     withIosContext:(const std::shared_ptr<flutter::IOSContext>&)iosContext
+          grContext:(GrDirectContext*)grContext;
+
+/// @brief Handler for platform view message channels.
+- (void)onMethodCall:(FlutterMethodCall*)call result:(FlutterResult)result;
+
+/// @brief Returns the platform view id if the platform view (or any of its descendant view) is
+/// the first responder.
+///
+/// Returns -1 if no such platform view is found.
+- (long)firstResponderPlatformViewId;
+
+/// @brief Pushes backdrop filter mutation to the mutator stack of each visited platform view.
+- (void)pushFilterToVisitedPlatformViews:(const std::shared_ptr<flutter::DlImageFilter>&)filter
+                                withRect:(const SkRect&)filterRect;
+
+/// @brief Pushes the view id of a visted platform view to the list of visied platform views.
+- (void)pushVisitedPlatformViewId:(int64_t)viewId;
+
+@end
+
+@interface FlutterPlatformViewsController (Testing)
+
+- (size_t)embeddedViewCount;
+
+// TODO(cbracken): Delete. This is unused.
+- (size_t)layerPoolSize;
+
+// Returns the `FlutterPlatformView`'s `view` object associated with the view_id.
+//
+// If the `PlatformViewsController` does not contain any `FlutterPlatformView` object or
+// a `FlutterPlatformView` object associated with the view_id cannot be found, the method
+// returns nil.
+- (UIView*)platformViewForId:(int64_t)viewId;
+
+// Composite the PlatformView with `viewId`.
+//
+// Every frame, during the paint traversal of the layer tree, this method is called for all
+// the PlatformViews in `_viewsToRecomposite`.
+//
+// Note that `_viewsToRecomposite` does not represent all the views in the view hierarchy,
+// if a PlatformView does not change its composition parameter from last frame, it is not
+// included in the `views_to_recomposite_`.
+- (void)compositeView:(int64_t)viewId withParams:(const flutter::EmbeddedViewParams&)params;
+
+- (const flutter::EmbeddedViewParams&)compositionParamsForView:(int64_t)viewId;
+
+@end
+
+#endif  // FLUTTER_SHELL_PLATFORM_DARWIN_IOS_FRAMEWORK_SOURCE_FLUTTERPLATFORMVIEWSCONTROLLER_H_