android_packages_apps_Benchmark/build.gradle at master · RTAndroid/android_packages_apps_Benchmark · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
/*
 * Copyright (C) 2017 RTAndroid Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

import org.apache.tools.ant.taskdefs.condition.Os

repositories {
    mavenCentral()
}

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.2.2'
    }
}

apply plugin: 'com.android.application'

dependencies {
    compile fileTree(dir: 'libs', include: '*.jar')
    compile 'com.android.support:support-v4:25.0.1'
    compile 'com.android.support:appcompat-v7:25.0.1'
    compile 'com.android.support:design:25.0.1'

    provided fileTree(dir: 'api', include: 'rtandroid-20161201.jar')
}

def getNdkExecutable() {
    Properties properties = new Properties()
    properties.load(project.rootProject.file('local.properties').newDataInputStream())
    def ndkDir = properties.getProperty('ndk.dir')
    if (Os.isFamily(Os.FAMILY_WINDOWS)) {
        "$ndkDir/ndk-build.cmd"
    }
    else {
        "$ndkDir/ndk-build"
    }
}

task buildNative(type: Exec) {
    commandLine getNdkExecutable(),
            '-C', file('jni').absolutePath,
            'NDK_LIBS_OUT=./../obj/shared'
            'APP_PLATFORM=android-22'
}

task cleanNative(type: Exec) {
    commandLine getNdkExecutable(),
            '-C', file('jni').absolutePath,
            'clean'
}

android {
    compileSdkVersion 25
    buildToolsVersion "25"

    defaultConfig {
        applicationId "rtandroid.benchmark"
        minSdkVersion 22
        targetSdkVersion 25
        versionCode 3
        versionName "3.0"
    }

    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            aidl.srcDirs = ['src']
            assets.srcDirs = ['assets']
            java.srcDirs = ['src']
            jni.srcDirs = []
            jniLibs.srcDirs = ['jniLibs']
            renderscript.srcDirs = ['src']
            resources.srcDirs = ['src']
            res.srcDirs = ['res']
        }

        instrumentTest.setRoot('tests')
        debug.setRoot('build/debug')
        release.setRoot('build/release')

        // consider native libraries on build and clean
        tasks.withType(JavaCompile) { compileTask -> compileTask.dependsOn buildNative }
        clean.dependsOn cleanNative
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }

    buildTypes {
        release {
            minifyEnabled true
            proguardFiles 'proguard.flags'
        }
        manual {
            initWith debug
            minifyEnabled false
            applicationIdSuffix ".manual"
        }
    }
}