NetworkCompatible/build.gradle.kts at master · Kas-tle/NetworkCompatible · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
/*
 * Copyright 2023 CloudburstMC
 *
 * CloudburstMC licenses this file to you under the Apache License,
 * version 2.0 (the "License"); you may not use this file except in compliance
 * with the License. You may obtain a copy of the License at:
 *
 *   https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
 * WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
 * License for the specific language governing permissions and limitations
 * under the License.
 */

plugins {
    alias(libs.plugins.nmcp.aggregation)
    `maven-publish`
}

repositories {
    mavenCentral()
}

subprojects {
    apply(plugin = "java-library")
    apply(plugin = "com.gradleup.nmcp")
    apply(plugin = "maven-publish")
    apply(plugin = "signing")

    group = "dev.kastle.netty"
    version = rootProject.property("version") as String

    repositories {
        mavenLocal()
        mavenCentral()
    }

    configure<JavaPluginExtension> {
        toolchain {
            languageVersion.set(JavaLanguageVersion.of(8))
        }
        withJavadocJar()
        withSourcesJar()
    }

    configure<PublishingExtension> {
        publications {
            create<MavenPublication>("maven") {
                artifactId = "netty-${project.name}"

                from(components["java"])

                pom {
                    description.set(project.name)
                    name.set(project.name)
                    url.set("https://github.com/Kas-tle/NetworkCompatible")
                    inceptionYear.set("2024")
                    licenses {
                        license {
                            name.set("The Apache License, Version 2.0")
                            url.set("https://www.apache.org/licenses/LICENSE-2.0.txt")
                        }
                    }
                    developers {
                        developer {
                            name.set("Kas-tle")
                            organization.set("Kas-tle")
                            organizationUrl.set("https://github.com/Kas-tle")
                        }
                    }
                    scm {
                        connection.set("scm:git:git://github.com/Kas-tle/NetworkCompatible.git")
                        developerConnection.set("scm:git:ssh://github.com:Kas-tle/NetworkCompatible.git")
                        url.set("https://github.com/Kas-tle/NetworkCompatible")
                    }
                    ciManagement {
                        system.set("GitHub Actions")
                        url.set("https://github.com/Kas-tle/NetworkCompatible/actions")
                    }
                    issueManagement {
                        system.set("GitHub Issues")
                        url.set("https://github.com/Kas-tle/NetworkCompatible/issues")
                    }
                }
            }
        }
    }

    configure<SigningExtension> {
        if (System.getenv("PGP_SECRET") != null && System.getenv("PGP_PASSPHRASE") != null) {
            useInMemoryPgpKeys(System.getenv("PGP_SECRET"), System.getenv("PGP_PASSPHRASE"))
            sign(project.extensions.getByType(PublishingExtension::class).publications["maven"])
        }
    }

    tasks {
        named<JavaCompile>("compileJava") {
            options.encoding = "UTF-8"
        }
        named<Test>("test") {
            minHeapSize = "512m"
            maxHeapSize = "1024m"
            jvmArgs = listOf("-XX:MaxMetaspaceSize=512m")
            useJUnitPlatform()
        }
    }
}

dependencies {
    allprojects {
        nmcpAggregation(project(path))
    }
}


nmcpAggregation {
    centralPortal {
        project(":transport-raknet")
        project(":transport-nethernet")

        username.set(System.getenv("MAVEN_CENTRAL_USERNAME"))
        password.set(System.getenv("MAVEN_CENTRAL_PASSWORD"))

        publishingType.set("AUTOMATIC")
    }
}