dependencies.gradle

//file:noinspection DependencyNotationArgument
// TODO remove when fixed in RFG ^
/*
 * Add your dependencies here. Supported configurations:
 *  - api("group:name:version:classifier"): if you use the types from this dependency in the public API of this mod
 *       Available at runtime and compiletime for mods depending on this mod
 *  - implementation("g:n:v:c"): if you need this for internal implementation details of the mod, but none of it is visible via the public API
 *       Available at runtime but not compiletime for mods depending on this mod
 *  - compileOnly("g:n:v:c"): if the mod you're building doesn't need this dependency during runtime at all, e.g. for optional mods
 *       Not available at all for mods depending on this mod, only visible at compiletime for this mod
 *  - compileOnlyApi("g:n:v:c"): like compileOnly, but also visible at compiletime for mods depending on this mod
 *       Available at compiletime but not runtime for mods depending on this mod
 *  - runtimeOnly("g:n:v:c"): if you want to include a mod in this mod's runClient/runServer runs, but not publish it as a dependency
 *       Not available at all for mods depending on this mod, only visible at runtime for this mod
 *  - devOnlyNonPublishable("g:n:v:c"): a combination of runtimeOnly and compileOnly for dependencies present at both compiletime and runtime,
 *       but not published as Maven dependencies - useful for RFG-deobfuscated dependencies or local testing
 *  - runtimeOnly("g:n:v:c"): if you don't need this at compile time, but want it to be present at runtime
 *       Available at runtime for mods depending on this mod
 *  - annotationProcessor("g:n:v:c"): mostly for java compiler plugins, if you know you need this, use it, otherwise don't worry
 *  - testCONFIG("g:n:v:c") - replace CONFIG by one of the above (except api), same as above but for the test sources instead of main
 *
 *  - shadowImplementation("g:n:v:c"): effectively the same as API, but the dependency is included in your jar under a renamed package name
 *       Requires you to enable usesShadowedDependencies in gradle.properties
 *       For more info, see https://github.com/GTModpackTeam/Buildscripts/blob/master/docs/shadow.md
 *
 * You can exclude transitive dependencies (dependencies of the chosen dependency) by appending { transitive = false } if needed,
 * but use this sparingly as it can break using your mod as another mod's dependency if you're not careful.
 *
 * To depend on obfuscated jars you can use `devOnlyNonPublishable(rfg.deobf("dep:spec:1.2.3"))` to fetch an obfuscated jar from maven,
 * or `devOnlyNonPublishable(rfg.deobf(project.files("libs/my-mod-jar.jar")))` to use a file.
 *
 * To add a mod with CurseMaven, replace '("g:n:v:c")' in the above with 'rfg.deobf("curse.maven:project_slug-project_id:file_id")'
 * Example: devOnlyNonPublishable(rfg.deobf("curse.maven:top-245211:2667280"))
 *
 * Gradle names for some of the configuration can be misleading, compileOnlyApi and runtimeOnly both get published as dependencies in Maven, but compileOnly does not.
 * The buildscript adds runtimeOnly to also have a runtime dependency that's not published.
 *
 * For more details, see https://docs.gradle.org/8.4/userguide/java_library_plugin.html#sec:java_library_configurations_graph
 */
dependencies {
    // Hard Dependencies
    implementation ("codechicken:codechickenlib:3.2.3.358") {
        transitive = false
    } // CCL 3.2.3.358

    implementation (rfg.deobf("gregtech:gregtech:2.8.10-beta")) {
        transitive = false
    } // CEu 2.8.10
    implementation (rfg.deobf("gregicality:GregicalityMultiblocks:1.2.11")) {
        transitive = false
    } // Version 1.2.11
    // runtimeOnly files("libs/gregtech-1.12.2-2.8.9-beta-dev.jar") // CEu pr 2.9.0
    implementation ("com.cleanroommc:groovyscript:1.1.3") {
        transitive = false
    } // Version 1.1.3

	compileOnly "CraftTweaker2:CraftTweaker2-MC1120-Main:1.12-4.1.20.700" // CrT 4.1.20.700
    compileOnly "curse.maven:ctm-267602:2915363" // CTM 1.0.2.31
    runtimeOnly "com.cleanroommc:modularui:2.4.3" // MUI 2.4.3

    // Debug Forestry
    implementation rfg.deobf("curse.maven:forestry-59751:5903382") // Forestry 5.8.2.387
    runtimeOnly rfg.deobf("curse.maven:jei-bees-248370:2490058") // JEIBees 0.9.0.5

    // Debug Gendustry
    compileOnly rfg.deobf("curse.maven:bdlib-70496:2518031") // BdLib 1.14.3.12
    compileOnly rfg.deobf("curse.maven:gendustry-70492:2516215") // Gendustry 1.6.5.8
    if (project.debug_all.toBoolean() || project.debug_gendustry.toBoolean()) {
        runtimeOnly rfg.deobf("curse.maven:bdlib-70496:2518031") // BdLib 1.14.3.12
        runtimeOnly rfg.deobf("curse.maven:gendustry-70492:2516215") // Gendustry 1.6.5.8
        runtimeOnly rfg.deobf("curse.maven:gendustry-jei-addon-301364:2609434") // Gendustry JEI Addon 1.0.2
    }

    // Debug Binnies
    compileOnly rfg.deobf("curse.maven:binnies-mods-patched-899182:7731146") // Binnie's Mods Patched 2.5.1.213
    if (project.debug_all.toBoolean() || project.debug_binnies.toBoolean()) {
        runtimeOnly rfg.deobf("curse.maven:binnies-mods-patched-899182:7731146") // Binnie's Mods Patched 2.5.1.213
    }

    // Debug GTFO: 1.12.5
    compileOnly rfg.deobf("curse.maven:gregtech-food-option-477021:6472136")
    if (project.debug_all.toBoolean() || project.debug_gtfo.toBoolean()) {
        runtimeOnly rfg.deobf("curse.maven:gregtech-food-option-477021:6472136")
    }
}