common-map-geospatial-notation/build.gradle at master · CMAPI/common-map-geospatial-notation · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:1.5.0'
    }
}

plugins {
    id "com.moowork.node"         version "0.11"
    id 'net.researchgate.release' version '2.3.5'
}

ext {
    group = "org.cmapi.primitives"

    description = "Common Map Geospatial Notation (CMGN)"

    nexusPublishUrl   = project.hasProperty('nexusPublishUrl') ? project.property('nexusPublishUrl') : ''

    di2eNexusUsername = project.hasProperty('empUsername') ? project.property('empUsername') : ''
    di2eNexusPassword = project.hasProperty('empPassword') ? project.property('empPassword') : ''
}

configure (rootProject) {
    apply plugin: 'java'
    apply plugin: 'maven-publish'
    apply plugin: 'com.moowork.node'

    repositories {
        jcenter()
    }

    def cmapiGeneratedDir   = file("$buildDir/generated/cmapi")
    def cmapiJsonSchemaFile = file("src/schema/geonotation.schema.json")

    sourceSets.main.java.srcDirs += "$cmapiGeneratedDir/dist/java"

    javadoc {
        source = sourceSets.main.allJava
        failOnError true
        exclude '**/*.md'
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        classifier 'javadoc'
        from javadoc.destinationDir
    }
    task sourceJar(type: Jar, dependsOn: classes) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    task generateJavaBindingsCMAPI(type: NodeTask, description: "Generates the CMAPI interface classes") {
        script = file("src/generator/generate.js")
        //args = ['-debug', '/../schema/geonotation.schema.json']

        execOverrides {
            it.workingDir = cmapiGeneratedDir
        }
        doFirst {
            cmapiGeneratedDir.mkdirs()
        }
        inputs.file "src/generator/generate.js"
        outputs.dir cmapiGeneratedDir
    }
    compileJava.dependsOn generateJavaBindingsCMAPI

    node {
        version  = '4.3.1'
        download = true
    }

    publishing {
        publications {
            mavenJava(MavenPublication) {
                groupId    = project.ext.group
                artifactId = project.name
                version    = project.version

                artifact jar
                artifact javadocJar
                artifact sourceJar
                artifact cmapiJsonSchemaFile
            }
        }
        repositories {
            maven {
                //url "$rootProject.buildDir/_repo1"
                url = nexusPublishUrl

                credentials {
                    username project.di2eNexusUsername
                    password project.di2eNexusPassword
                }
            }
        }
        if (project.hasProperty('di2eNexusReleaseUrl')) {
            repositories {
                maven {
                    //url "$rootProject.buildDir/_repo2"
                    url = project.property('di2eNexusReleaseUrl')

                    credentials {
                        username project.di2eNexusUsername
                        password project.di2eNexusPassword
                    }
                }
            }
        }
    }

    release {
        buildTasks = ['releaseBuild']
        tagTemplate = 'v${version}'

        git {
            requireBranch = project.hasProperty('release_requireBranch') ? project.property('release_requireBranch') : 'FAIL'
        }
    }

    task releaseBuild {
        dependsOn allprojects.collect { it.tasks.withType(PublishToMavenRepository) }
    }
}

task wrapper(type: Wrapper, description: "Generates gradlew[.bat] scripts") {
    gradleVersion = '2.12'
}

if (JavaVersion.current().isJava8Compatible()) { // disable lint for java8
    allprojects {
        tasks.withType(Javadoc) {
            options.addStringOption('Xdoclint:none', '-quiet')
        }
    }
}