BuildTeamTools/build.gradle.kts at main · BuildTheEarth/BuildTeamTools · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
plugins {
    java
    alias(libs.plugins.lombok)
    alias(libs.plugins.git.version)
    alias(libs.plugins.shadow)
}

dependencies {
    //implementation(libs.com.alpsbte.alpslib.alpslib.libpsterra) CURRENTLY BROKEN
    implementation(libs.alpslib.io)
    implementation(libs.alpslib.utils)   {
        exclude(group = "com.github.cryptomorin", module = "XSeries")
    }
    implementation(libs.com.alpsbte.canvas)
    implementation(libs.com.github.cryptomorin.xseries)
    implementation(libs.net.wesjd.anvilgui)
    implementation(libs.micycle.clipper2)
    implementation(libs.org.json.json)
    implementation(libs.com.google.code.gson.gson)
    implementation(libs.com.squareup.okhttp3.okhttp.jvm)
    implementation(libs.javaapiforkml) {
        exclude(group = "com.sun.xml.bind", module = "jaxb-xjc") // Else Remapping will yell of duplicated classes
    }
    implementation(libs.com.googlecode.json.simple)
    implementation(libs.bstats.bukkit)
    implementation(platform(libs.fawe.bom))
    compileOnly("com.fastasyncworldedit:FastAsyncWorldEdit-Core")
    compileOnly("com.fastasyncworldedit:FastAsyncWorldEdit-Bukkit") { isTransitive = false }
    compileOnly(libs.io.papermc.paper.paper.api)
    compileOnly(libs.bluemap.api)
}

val versionDetails: groovy.lang.Closure<com.palantir.gradle.gitversion.VersionDetails> by extra
val details = versionDetails()

group = "net.buildtheearth"
version = "0.2.0" + "-alpha" //+ details.gitHash + "-SNAPSHOT"
description = "BuildTeamTools"
java.sourceCompatibility = JavaVersion.VERSION_21
java.targetCompatibility = JavaVersion.VERSION_21

tasks.withType<JavaCompile> {
    options.encoding = "UTF-8"
}

tasks.withType<Javadoc> {
    options.encoding = "UTF-8"
}

tasks.shadowJar {
    archiveClassifier = ""

    relocationPrefix = "net.buildtheearth.buildteamtools.shaded"
    enableAutoRelocation = true
}

tasks.assemble {
    dependsOn(tasks.shadowJar) // Ensure that the shadowJar task runs before the build task
}

tasks.jar {
    archiveClassifier = "UNSHADED"
    enabled = false // Disable the default jar task since we are using shadowJar
}

tasks.processResources {
    // work around IDEA-296490
    duplicatesStrategy = DuplicatesStrategy.INCLUDE
    with(copySpec {
        from("src/main/resources/plugin.yml") {
            expand(
                mapOf(
                    "version" to project.version,
                    "description" to project.description
                )
            )
        }
    })
}